0  BEGIN PGM 9035_en MM 
1  ;NC program for automatically finding the 
2  ;file name and engraving it onto the 
3  ;workpiece through a cycle.
4  ;The control calls a mask file. This writes
5  ;the file path into a text file. The control
6  ;then calls a program with which it selects
7  ;the program name fron the file path. The
8  ;control saves the file name in QS1. It loads
9  ;QS1 in a return jump into this program and
10 ;used it in the engraving cycle 225.
11 ;If the three files being used are not in 
12 ;the same directorz, you have to adapt the
13 ;path data in calls.
14 ;IMPORTANT! The program does not run in the
15 ;program test, because copying a text file
16 ;into  an NC program is not allowed there!
17 ;
18 BLK FORM 0.1 Z  X+0  Y+0  Z-20
19 BLK FORM 0.2  X+100  Y+100  Z+0
20 ;
21 ;Tool call, engraving tool
22 TOOL CALL 151 Z S6000
23 M3
24 ;
25 L  Z+100 R0 FMAX
26 ;
27 ;Write the content of the "mask" file into
28 ;the "File". The program name is entered 
29 ;using the syntax.
30 FN 16: F-PRINT mask.a / FILE.a
31 ;
32 ;Call a program for forming the text string
33 CALL PGM 90351_en.H
34 ;
35 ;
36 ;Engrave the file name contained in QS1
37 CYCL DEF 225 GRAVIEREN ~
    QS500= QS1     ;GRAVIERTEXT ~
    Q513=+10   ;ZEICHENHOEHE ~
    Q514=+0    ;FAKTOR ABSTAND ~
    Q515=+0    ;SCHRIFTART ~
    Q516=+0    ;TEXTANORDNUNG ~
    Q374=+0    ;DREHLAGE ~
    Q517=+50   ;KREISRADIUS ~
    Q207=+500  ;VORSCHUB FRAESEN ~
    Q201=-0.3  ;TIEFE ~
    Q206=+150  ;VORSCHUB TIEFENZ. ~
    Q200=+2    ;SICHERHEITS-ABST. ~
    Q203=+0    ;KOOR. OBERFLAECHE ~
    Q204=+50   ;2. SICHERHEITS-ABST.
38 ;
39 ;Call cycle at starting point
40 L  X+20  Y+40 R0 FMAX M99
41 ;
42 ;Retract
43 L  Z+100 R0 FMAX
44 ;
45 ;End of program
46 M30
47 END PGM 9035_en MM