BEGIN PGM 82453_EN MM 
;NC program for measuring points in
;3-D and documenting the measurement
;result in a log.
;Calibrate the touch probe in 3-D
;with the cycle in order to perform
;a 3-D measurement.
;
M140 MB MAX
;
;Tool call: touch probe
TOOL CALL "TOUCH_PROBE" Z S11
;
;Tilt the working plane into position
PLANE SPATIAL SPA+0 SPB+0 SPC+0 TURN MB MAX FMAX SEQ-
;
;Pre-position
L  X+0  Y+0 R0 FMAX M7
L  Z+25 R0 FMAX
;Definition of measured values, point 1
QL1 = - 3.7059 ;X COORDINATE, POINT 1
QL2 = 9 ;Y COORDINATE, POINT 1
QL3 = - 0.1704 ;Z COORDINATE, POINT 1
QL11 = 0.258819 ;NORMAL IN REF. AXIS
QL12 = 0 ;NORMAL IN MINOR AXIS
QL13 = 0.9659258 ;NORMAL IN TOOL AXIS
;Call subprogram for measurement 
CALL LBL "Probe"
;
;Definition of measured values, point 2
QL1 = - 2.5 ;X COORDINATE, POINT 2
QL2 = 9 ;Y COORDINATE, POINT 2
QL3 = - 0.6699 ;Z COORDINATE, POINT 2
QL11 = 0.5 ;NORMAL IN REF. AXIS
QL12 = 0 ;NORMAL IN MINOR AXIS
QL13 = 0.8660254 ;NORMAL IN TOOL AXIS
;Call subprogram for measurement
CALL LBL "Probe"
;
;Definition of measured values, point 3
QL1 = - 1.4645 ;X COORDINATE, POINT 3
QL2 = 9 ;Y COORDINATE, POINT 3
QL3 = - 1.4645 ;Z COORDINATE, POINT 3
QL11 = 0.7071068 ;NORMAL IN REF. AXIS
QL12 = 0 ;NORMAL IN MINOR AXIS
QL13 = 0.7071068 ;NORMAL IN TOOL AXIS
;Call subprogram for measurement
CALL LBL "Probe"
;
;Definition of measured values, point 4
QL1 = - 0.6699 ;X COORDINATE, POINT 4
QL2 = 9 ;Y COORDINATE, POINT 4
QL3 = - 2.5 ;Z COORDINATE, POINT 4 
QL11 = 0.8660254 ;NORMAL IN REF. AXIS
QL12 = 0 ;NORMAL IN MINOR AXIS
QL13 = 0.5 ;NORMAL IN TOOL AXIS
;Call subprogram for measurement
CALL LBL "Probe"
;
;Definition of measured values, point 5
QL1 = - 0.1704 ;X COORDINATE, POINT 5
QL2 = 9 ;Y COORDINATE, POINT 5
QL3 = - 3.7059 ;Z COORDINATE, POINT 5
QL11 = 0.9659258 ;NORMAL IN REF. AXIS
QL12 = 0 ;NORMAL IN MINOR AXIS
QL13 = 0.258819 ;NORMAL IN TOOL AXIS
;Call subprogram for measurement
CALL LBL "Probe"
;
;Go to end of program
FN 9: IF +0 EQU +0 GOTO LBL "End"
;
;Subprogram: measuring
LBL "Probe"
TCH PROBE 444 ANTASTEN 3D ~
   Q263=+QL1  ;1. PUNKT 1. ACHSE ~
    Q264=+QL2  ;1. PUNKT 2. ACHSE ~
    Q294=+QL3  ;1. PUNKT 3. ACHSE ~
    Q581=+QL11 ;NORMALE HAUPTACHSE ~
    Q582=+QL12 ;NORMALE NEBENACHSE ~
    Q583=+QL13 ;NORMALE WKZ-ACHSE ~
    Q320=+2    ;SICHERHEITS-ABST. ~
    Q260=+25   ;SICHERE HOEHE ~
    QS400="0.015-0.015" ;TOLERANZ ~
    Q309=+0    ;FEHLERREAKTION
LBL 0
LBL "End"
M129 M9
END PGM 82453_EN MM