0  BEGIN PGM 5085-en MM 
1  ;In this program a circular stud and a
2  ;circular pocket are milled on a tilted
3  ;working plane. Then chamfers are milled, with
4  ;an inclined tool, on the contours. The pocket
5  ;and the stud are programed with cycles. For
6  ;the chamfers, you must define the parameters
7  ;from which the control calculates the tool
8  ;path.
9  ;
10 BLK FORM 0.1 Z  X-50  Y-50  Z-40
11 BLK FORM 0.2  X+50  Y+50  Z+10
12 TOOL CALL 8 Z S12000 F5000 ;Cutter diameter 16
13 * - Tilt working plane
14 PLANE SPATIAL SPA+10 SPB+0 SPC+0 TURN MB100 FMAX
15 CYCL DEF 232 FACE MILLING ~
    Q389=+1    ;STRATEGY ~
    Q225=-50   ;STARTNG PNT 1ST AXIS ~
    Q226=-60   ;STARTNG PNT 2ND AXIS ~
    Q227=+20   ;STARTNG PNT 3RD AXIS ~
    Q386=+0    ;END POINT 3RD AXIS ~
    Q218=+100  ;FIRST SIDE LENGTH ~
    Q219=+120  ;2ND SIDE LENGTH ~
    Q202=+20   ;MAX. PLUNGING DEPTH ~
    Q369=+0    ;ALLOWANCE FOR FLOOR ~
    Q370=+1    ;MAX. OVERLAP ~
    Q207= AUTO ;FEED RATE FOR MILLNG ~
    Q385= AUTO ;FINISHING FEED RATE ~
    Q253= MAX ;F PRE-POSITIONING ~
    Q200=+2    ;SET-UP CLEARANCE ~
    Q357=+2    ;CLEARANCE TO SIDE ~
    Q204=+50   ;2ND SET-UP CLEARANCE
16 M3 M99
17 CYCL DEF 252 CIRCULAR POCKET ~
    Q215=+0    ;MACHINING OPERATION ~
    Q223=+60   ;CIRCLE DIAMETER ~
    Q368=+0    ;ALLOWANCE FOR SIDE ~
    Q207=+500  ;FEED RATE FOR MILLNG ~
    Q351=+1    ;CLIMB OR UP-CUT ~
    Q201=-10   ;DEPTH ~
    Q202=+10   ;PLUNGING DEPTH ~
    Q369=+0    ;ALLOWANCE FOR FLOOR ~
    Q206=+150  ;FEED RATE FOR PLNGNG ~
    Q338=+0    ;INFEED FOR FINISHING ~
    Q200=+2    ;SET-UP CLEARANCE ~
    Q203=+0    ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q370=+1    ;TOOL PATH OVERLAP ~
    Q366=+1    ;PLUNGE ~
    Q385=+500  ;FINISHING FEED RATE
18 L  X+0  Y+0 R0 FMAX M3 M99
19 CYCL DEF 257 CIRCULAR STUD ~
    Q223=+100  ;FINISHED PART DIA. ~
    Q222=+142  ;WORKPIECE BLANK DIA. ~
    Q368=+0    ;ALLOWANCE FOR SIDE ~
    Q207=+500  ;FEED RATE FOR MILLNG ~
    Q351=+1    ;CLIMB OR UP-CUT ~
    Q201=-10   ;DEPTH ~
    Q202=+10   ;PLUNGING DEPTH ~
    Q206=+3000 ;FEED RATE FOR PLNGNG ~
    Q200=+2    ;SET-UP CLEARANCE ~
    Q203=+0    ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q370=+1    ;TOOL PATH OVERLAP ~
    Q376=-1    ;STARTING ANGLE
20 L  X+0  Y+0 R0 FMAX M3 M99
21 ;
22 * -Parameters first chamfer
23 Q1 = 5 ;CHAMFER LENGTH
24 Q2 = 45 ;CHAMFER ANGLE
25 Q3 = 100 ;DIAMETER CIRCLE
26 Q4 = 1 ;1=OUTSIDE 2=INSIDE PROCESSING
27 TOOL CALL  DL-0.5 ;Overflow to get smooth edges
28 CALL LBL "chamfer"
29 PLANE SPATIAL SPA+10 SPB+0 SPC+0 TURN MB100 FMAX
30 ;
31 * -Parameter secound chamfer
32 Q1 = 5 ;CHAMFER LENGTH
33 Q2 = 45 ;CHAMFER ANGLE
34 Q3 = 60 ;DIAMETER CIRCLE
35 Q4 = 2 ;1=OUTSIDE 2=INSIDE PROCESSING
36 TOOL CALL  DL-0.5 ;Overflow to get smooth edges
37 CALL LBL "chamfer"
38 ;
39 M2
40 LBL "chamfer"
41 ;Query whether inside or outside processing
42 FN 9: IF +Q4 EQU +1 GOTO LBL "inside"
43 FN 9: IF +Q4 EQU +2 GOTO LBL "outside"
44 STOP
45 ;Please choose Q4 -inside or outside processing
46 ;
47 LBL "inside"
48 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
49 Q10 = Q108 * ( COS Q2 ) ;Calculate tool radius correction
50 Q11 = ( Q3 / 2 ) - Q10 ;Diameter - Tool radius correction
51 Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Tool correction Z-axis
52 QL11 = Q11 - Q108 ;Preposition Y
53 QL12 = Q12 - 2 ;Preposition Z
54 L  X-Q108  Y-QL11  Z+50 R0 FMAX
55 L  A+Q2  B+0  C+0 R0 FMAX ;Imprortant to enter all three rotarz axis,~
 because Function TCPM ... AXIS SPAT is used
56 L  Z-QL12 R0 F AUTO
57 CC  X+0  Y-QL11
58 CP  PA-90  Z-Q12 DR+
59 QL1 = 270
60 LBL 1
61 QL1 = QL1 + 1
62 QL2 = Q11 * COS QL1
63 QL3 = Q11 * SIN QL1
64 L  X+QL2  Y+QL3 IC+1
65 CALL LBL 1 REP359
66 CC  X+0  Y-QL11
67 CP  PA+0  Z-QL12 DR+
68 M140 MB+20
69 FN 9: IF +0 EQU +0 GOTO LBL "reset"
70 ;
71 LBL "outside"
72 FUNCTION TCPM F TCP AXIS SPAT PATHCTRL VECTOR
73 Q10 = Q108 * ( COS Q2 ) ;Calculate tool radius correction
74 Q11 = ( Q3 / 2 ) + Q10 ;Diameter + tool radius correction
75 Q12 = ( Q1 / TAN Q2 ) - ( SIN Q2 * Q108 ) ;Tool correction Z-axis
76 QL11 = Q11 + Q108 ;Preposition Y
77 QL12 = Q12 - 2 ;Preposition Z
78 L  X+Q108  Y-QL11  Z+50 R0 FMAX
79 L  A-Q2  B+0  C+0 R0 FMAX ;Important to enter all three rotary axis,~
 because Function TCPM ... AXIS SPAT is used.
80 L  Z-QL12 R0 F AUTO
81 CC  X+0  Y-QL11
82 CP IPA+90  Z-Q12 DR+
83 QL1 = 270
84 LBL 2
85 QL1 = QL1 - 1
86 QL2 = Q11 * COS QL1
87 QL3 = Q11 * SIN QL1
88 L  X+QL2  Y+QL3 IC-1
89 CALL LBL 2 REP359
90 CC  X+0  Y-QL11
91 CP  PA+180  Z-QL12 DR+
92 M140 MB+20
93 ;
94 LBL "reset"
95 FUNCTION RESET TCPM
96 * -Move to a save position
97 L  Z+500 R0 FMAX M91
98 L  X+800  Y+600 R0 FMAX M91
99 * -Reset tilted working plane
100 PLANE RESET TURN FMAX
101 LBL 0
102 END PGM 5085-en MM