0  BEGIN PGM 50051_EN MM 
1  ;Program for machining a circular stud 
2  ;and then milling the surface at a slant.
3  ;
4  ;Tool call
5  TOOL CALL 15 Z S4000 F300
6  ;
7  L  Z+100 R0 FMAX M3 ;Move to clearance height
8  L  X+Q7  Y+Q8 R0 FMAX ;Pre-position
9  FN 3: Q80 =+Q1 * +2 ;Calculation of diameter
10 ;Definition of circular stud
11 CYCL DEF 257 CIRCULAR STUD ~
    Q223=+Q80  ;FINISHED PART DIA. ~
    Q222=+141  ;WORKPIECE BLANK DIA. ~
    Q368=+0    ;ALLOWANCE FOR SIDE ~
    Q207=+600  ;FEED RATE FOR MILLNG ~
    Q351=+1    ;CLIMB OR UP-CUT ~
    Q201=-50   ;DEPTH ~
    Q202=+10   ;PLUNGING DEPTH ~
    Q206=+3000 ;FEED RATE FOR PLNGNG ~
    Q200=+2    ;SET-UP CLEARANCE ~
    Q203=+0    ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q370=+1    ;TOOL PATH OVERLAP ~
    Q376=+0    ;STARTING ANGLE
12 M99
13 L  X+Q7  Y+Q8  Z+100 R0 FMAX
14 ;Shift the datum to the stud center.
15 ;Shift Z to the position 
16 ;that the working plane is tilted around.
17 CYCL DEF 7.0 DATUM SHIFT
18 CYCL DEF 7.1  Z+Q9
19 CYCL DEF 7.2  X+Q7
20 CYCL DEF 7.3  Y+Q8
21 ;Tilt the working plane
22 CYCL DEF 19.0 WORKING PLANE
23 CYCL DEF 19.1  A+Q11  B+0  C+0
24 ;Move the rotary axis to the desired position.
25 L  A+Q120  B+Q121  C+Q122 R0 FMAX
26 ;Define cycle for face milling
27 CYCL DEF 232 FACE MILLING ~
    Q389=+2    ;STRATEGY ~
    Q225=-Q1   ;STARTNG PNT 1ST AXIS ~
    Q226=-60   ;STARTNG PNT 2ND AXIS ~
    Q227=+40   ;STARTNG PNT 3RD AXIS ~
    Q386=+0    ;END POINT 3RD AXIS ~
    Q218=+Q80  ;FIRST SIDE LENGTH ~
    Q219=+120  ;2ND SIDE LENGTH ~
    Q202=+5    ;MAX. PLUNGING DEPTH ~
    Q369=+0    ;ALLOWANCE FOR FLOOR ~
    Q370=+1    ;MAX. OVERLAP ~
    Q207=+600  ;FEED RATE FOR MILLNG ~
    Q385=+500  ;FINISHING FEED RATE ~
    Q253= MAX ;F PRE-POSITIONING ~
    Q200=+2    ;SET-UP CLEARANCE ~
    Q357=+2    ;CLEARANCE TO SIDE ~
    Q204=+50   ;2ND SET-UP CLEARANCE
28 M99
29 M140 MB MAX F9999 ;Retract
30 ;Cancel tilting the working plane
31 CYCL DEF 19.0 WORKING PLANE
32 CYCL DEF 19.1  A+0  B+0  C+0
33 CYCL DEF 19.0 WORKING PLANE
34 CYCL DEF 19.1
35 ;Reset rotary axes to zero
36 L  A+Q120  B+Q121  C+Q122 R0 FMAX
37 ;Cancel datum shift
38 CYCL DEF 7.0 DATUM SHIFT
39 CYCL DEF 7.1  X+0
40 CYCL DEF 7.2  Y+0
41 CYCL DEF 7.3  Z+0
42 END PGM 50051_EN MM