0  BEGIN PGM 4040-en MM 
1  BLK FORM 0.1 Z  X-100  Y-100  Z-100
2  BLK FORM 0.2  X+100  Y+100  Z+0
3  ;Milling circular stud
4  ;Tool call
5  TOOL CALL 10 Z S3000 F800
6  L  X+0  Y+0  Z+100 R0 FMAX M3
7  CYCL DEF 257 CIRCULAR STUD ~
    Q223=+200  ;FINISHED PART DIA. ~
    Q222=+283  ;WORKPIECE BLANK DIA. ~
    Q368=+0    ;ALLOWANCE FOR SIDE ~
    Q207= AUTO ;FEED RATE FOR MILLNG ~
    Q351=+1    ;CLIMB OR UP-CUT ~
    Q201=-80   ;DEPTH ~
    Q202=+5    ;PLUNGING DEPTH ~
    Q206= AUTO ;FEED RATE FOR PLNGNG ~
    Q200=+2    ;SET-UP CLEARANCE ~
    Q203=+0    ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q370=+1    ;TOOL PATH OVERLAP
8  M99
9  L  Z+100 R0 FMAX M5
10 ;Slots on cylindrical surface
11 ;Tool call
12 TOOL CALL 2 Z S5000 F500
13 ;Move to a save position for tilting the A-Axis
14 L  X+0  Y+0 R0 FMAX M3
15 M140 MB MAX F5000
16 ;Tilting the A-Axis
17 PLANE AXIAL  A-90 TURN FMAX
18 CALL LBL "Processing"
19 LBL "Stroke"
20 ;Inkremental movement of the C-Axis
21 PLANE AXIAL IC+10 TURN FMAX
22 CALL LBL "Processing"
23 ;Repetition of the stroke
24 CALL LBL "Stroke" REP34
25 M140 MB MAX F5000
26 PLANE RESET TURN FMAX
27 M30 ;End of program
28 ;Subprogram
29 LBL "Processing"
30 ;Processing cycle
31 ;Important! Surface coordinate is equal to cylindrical radius
32 CYCL DEF 253 SLOT MILLING ~
    Q215=+0    ;MACHINING OPERATION ~
    Q218=+20   ;SLOT LENGTH ~
    Q219=+5    ;SLOT WIDTH ~
    Q368=+0    ;ALLOWANCE FOR SIDE ~
    Q374=+100  ;ANGLE OF ROTATION ~
    Q367=+0    ;SLOT POSITION ~
    Q207=+500  ;FEED RATE FOR MILLNG ~
    Q351=+1    ;CLIMB OR UP-CUT ~
    Q201=-5    ;DEPTH ~
    Q202=+5    ;PLUNGING DEPTH ~
    Q369=+0    ;ALLOWANCE FOR FLOOR ~
    Q206=+150  ;FEED RATE FOR PLNGNG ~
    Q338=+0    ;INFEED FOR FINISHING ~
    Q200=+2    ;SET-UP CLEARANCE ~
    Q203=+100  ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q366=+0    ;PLUNGE ~
    Q385=+500  ;FINISHING FEED RATE
33 ;Position for Cycl call
34 L  X+0  Y+25 R0 FMAX M99
35 LBL 0
36 END PGM 4040-en MM