0  BEGIN PGM 2130_EN MM 
1  ;Program for milling a pocket with the contour
2  ;of a P3G polygon profile according to
3  ;ISO 32711
4  BLK FORM 0.1 Z X+0 Y+0 Z-25
5  BLK FORM 0.2  X+100  Y+100  Z+0
6  ;
7  ;Tool call milling tool diameter 20mm
8  TOOL CALL 10 Z S5000
9  ;
10 ;Cutting data
11 Q50 = 20 ;MILLING DEPTH
12 Q51 = 3 ;PLUNGING DEPTH
13 Q52 = 2 ;SET UP CLEARANCE
14 Q53 = 150 ;FEED RATE FOR PLUNGING
15 Q54 = 500 ;FEED RATE FOR MILLING
16 ;
17 ;Parameter for P3G polygon
18 Q30 = 75 ;ORBIFORM DIAMETER (D1)
19 Q31 = 3.15 ;ECCENTRIC SIZE (E)
20 Q36 = 50 ;CENTER OF THE POLYGON IN THE X AXIS
21 Q37 = 50 ;CENTER OF THE POLYGON IN THE Y AXIS
22 Q38 = 0 ;ROTATION
23 ;
24 ;===========================================
25 Q35 = 0 ;START ANGLE FOR STEP
26 CYCL DEF 7.0 DATUM SHIFT
27 CYCL DEF 7.1  X+Q36
28 CYCL DEF 7.2  Y+Q37
29 CYCL DEF 10.0 ROTATION
30 CYCL DEF 10.1  ROT+Q38
31 CYCL DEF 14.0 CONTOUR
32 CYCL DEF 14.1 CONTOUR LABEL1
33 CYCL DEF 20 CONTOUR DATA ~
    Q1=-Q50  ;MILLING DEPTH ~
    Q2=+1    ;TOOL PATH OVERLAP ~
    Q3=+0    ;ALLOWANCE FOR SIDE ~
    Q4=+0    ;ALLOWANCE FOR FLOOR ~
    Q5=+0    ;SURFACE COORDINATE ~
    Q6=+Q52  ;SET-UP CLEARANCE ~
    Q7=+50   ;CLEARANCE HEIGHT ~
    Q8=+0    ;ROUNDING RADIUS ~
    Q9=+1    ;ROTATIONAL DIRECTION
34 CYCL DEF 22 ROUGH-OUT ~
    Q10=-Q51  ;PLUNGING DEPTH ~
    Q11=+Q53  ;FEED RATE FOR PLNGNG ~
    Q12=+Q54  ;FEED RATE F. ROUGHNG ~
    Q18=+0    ;COARSE ROUGHING TOOL ~
    Q19=+0    ;FEED RATE FOR RECIP. ~
    Q208=+99999 ;RETRACTION FEED RATE
35 L  X+0  Y+0 R0 FMAX M3 M99
36 CYCL DEF 10.0 ROTATION
37 CYCL DEF 10.1  ROT+0
38 CYCL DEF 7.0 DATUM SHIFT
39 CYCL DEF 7.1  X+0
40 CYCL DEF 7.2  Y+0
41 ;
42 ;End of program
43 L  Z+50 R0 FMAX M30
44 ;
45 ;Sub program
46 ;Calculation of the contour points
47 LBL 1
48 Q40 = ( ( Q30 / 2 ) - Q31 * COS ( 3 * Q35 ) ) * COS Q35 - 3 * Q31 * SIN ( 3 * Q35 ) * SIN Q35
49 Q41 = ( ( Q30 / 2 ) - Q31 * COS ( 3 * Q35 ) ) * SIN Q35 + 3 * Q31 * SIN ( 3 * Q35 ) * COS Q35
50 L  X+Q40  Y+Q41 RL
51 Q35 = Q35 + 0.5
52 FN 10: IF +Q35 NE +360.5 GOTO LBL 1
53 LBL 0
54 END PGM 2130_EN MM