0  BEGIN PGM 10010_EN MM 
1  ;Milled-turned workpiece
2  ;The blank is for the workpiece to be
3  ;machined with Program 10005_en.h.
4  ;
5  ;Workpiece blank defenition as rotationally
6  ;symmetric objekt whose contour is defined
7  ;in the subprogram "BLANK"
8  BLK FORM ROTATION Z DIM_D LBL "BLANK"
9  ;
10 ;Activate the datum
11 CYCL DEF 247 DATUM SETTING ~
    Q339=+2    ;DATUM NUMBER
12 ;
13 ;Lathe machining, outside roughing
14 ;Tool call for turning tool, roughing
15 TOOL CALL "TURN_ROUGH"
16 ;
17 ;Subprogram call, turning mode
18 CALL LBL "TURN"
19 ;Subprogram call, move to save position
20 CALL LBL "SAVE"
21 ;
22 ;Adapting the rotary coordinate system
23 CYCL DEF 800 ADJUST XZ SYSTEM ~
    Q497=+0    ;PRECESSION ANGLE ~
    Q498=+0    ;REVERSE TOOL ~
    Q530=+0    ;INCLINED MACHINING ~
    Q531=+0    ;ANGLE OF INCIDENCE? ~
    Q532=+750  ;FEED RATE ~
    Q533=+0    ;PREFERRED DIRECTION ~
    Q535=+3    ;ECCENTRIC TURNING ~
    Q536=+0    ;ECCENTRIC W/O STOP
24 ;
25 ;Define the constant surface speed and
26 ;max. spindle speed
27 FUNCTION TURNDATA SPIN VCONST:ON VC:400 SMAX800
28 ;
29 ;Move tilting axis to zero and switch-on
30 ;turning spindle
31 L  A+0 R0 FMAX M303
32 ;
33 ;Face turning
34 CYCL DEF 821 SHOULDER, FACE ~
    Q215=+0    ;MACHINING OPERATION ~
    Q460=+2    ;SAFETY CLEARANCE ~
    Q493=+0    ;DIAMETER AT CONTOUR END ~
    Q494=+0    ;CONTOUR END IN Z ~
    Q463=+3    ;MAX. CUTTING DEPTH ~
    Q478=+0.3  ;ROUGHING FEED RATE ~
    Q483=+0.4  ;OVERSIZE FOR DIAMETER ~
    Q484=+0.2  ;OVERSIZE IN Z ~
    Q505=+0.2  ;FINISHING FEED RATE ~
    Q506=+0    ;CONTOUR SMOOTHING
35 L  X+122  Y+0 R0 FMAX ;Pre-positioning
36 L  Z+5 R0 FMAX ;Move to starting height
37 M99 ;Cycle call
38 ;
39 ;Contour turning
40 CYCL DEF 14.0 CONTOUR
41 CYCL DEF 14.1 CONTOUR LABEL1
42 CYCL DEF 810 TURN CONTOUR LONG. ~
    Q215=+0    ;MACHINING OPERATION ~
    Q460=+2    ;SAFETY CLEARANCE ~
    Q499=+0    ;REVERSE CONTOUR ~
    Q463=+3    ;MAX. CUTTING DEPTH ~
    Q478=+0.3  ;ROUGHING FEED RATE ~
    Q483=+0.4  ;OVERSIZE FOR DIAMETER ~
    Q484=+0.2  ;OVERSIZE IN Z ~
    Q505=+0.2  ;FINISHING FEED RATE ~
    Q487=+1    ;PLUNGE ~
    Q488=+0    ;PLUNGING FEED RATE ~
    Q479=+0    ;CONTOUR MACHINING LIMIT ~
    Q480=+0    ;DIAMETER LIMIT VALUE ~
    Q482=+0    ;LIMIT VALUE Z ~
    Q506=+0    ;CONTOUR SMOOTHING
43 L  X+122  Y+0 R0 FMAX ;Pre-positioning
44 L  Z+5 R0 FMAX ;Move to starting height
45 M99 ;Cycle call
46 ;
47 ;Milling surfaces and holes
48 ;Subprogram call, milling mode
49 CALL LBL "MILL"
50 ;Subprogram call, move to save position
51 CALL LBL "SAVE"
52 ;
53 ;Tool call for end mill
54 TOOL CALL "MILL_D20_ROUGH" Z S3000 F500
55 ;
56 ;Hole in center
57 L  X+0  Y+0  Z+50 R0 FMAX M3 ;Pre-positioning
58 CYCL DEF 208 BORE MILLING ~
    Q200=+2    ;SET-UP CLEARANCE ~
    Q201=-40   ;DEPTH ~
    Q206= AUTO ;FEED RATE FOR PLNGNG ~
    Q334=+1.5  ;PLUNGING DEPTH ~
    Q203=+0    ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q335=+32   ;NOMINAL DIAMETER ~
    Q342=+0    ;ROUGHING DIAMETER ~
    Q351=+1    ;CLIMB OR UP-CUT
59 M99 ;Cycle call
60 ;
61 ;Subprogram call, move to save position
62 CALL LBL "SAVE"
63 ;
64 ;Tool call for end mill
65 TOOL CALL "MILL_D10_ROUGH" Z S12000 F300
66 ;
67 Q50 = 0 ;Current C angle
68 ;
69 ;Repetition for tilting to position and
70 ;surface milling
71 LBL 2
72 PLANE SPATIAL SPA+0 SPB+0 SPC+Q50 STAY ;Tilting the coordinate system to the current C angle
73 ;
74 ;Move datum to the tilting edge
75 CYCL DEF 7.0 DATUM SHIFT
76 CYCL DEF 7.1  X+37
77 ;
78 PLANE RELATIV SPB+60 TURN MB MAX FMAX ;Tilt B with respect to C angle
79 ;
80 ;Surface milling
81 L  X+12  Y+0  Z+50 R0 FMAX M3 ;Pre-positioning
82 CYCL DEF 251 RECTANGULAR POCKET ~
    Q215=+0    ;MACHINING OPERATION ~
    Q218=+28   ;FIRST SIDE LENGTH ~
    Q219=+50   ;2ND SIDE LENGTH ~
    Q220=+0    ;CORNER RADIUS ~
    Q368=+0    ;ALLOWANCE FOR SIDE ~
    Q224=+0    ;ANGLE OF ROTATION ~
    Q367=+0    ;POCKET POSITION ~
    Q207= AUTO ;FEED RATE FOR MILLNG ~
    Q351=+1    ;CLIMB OR UP-CUT ~
    Q201=-12   ;DEPTH ~
    Q202=+5    ;PLUNGING DEPTH ~
    Q369=+0    ;ALLOWANCE FOR FLOOR ~
    Q206= AUTO ;FEED RATE FOR PLNGNG ~
    Q338=+0    ;INFEED FOR FINISHING ~
    Q200=+2    ;SET-UP CLEARANCE ~
    Q203=+12   ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q370=+1    ;TOOL PATH OVERLAP ~
    Q366=+0    ;PLUNGE ~
    Q385= AUTO ;FINISHING FEED RATE
83 M99 ;Cycle call
84 ;
85 M140 MB MAX ;Retracting
86 PLANE RESET STAY ;Tilt back mathematically
87 ;Reset the datum shift
88 CYCL DEF 7.0 DATUM SHIFT
89 CYCL DEF 7.1  X+0
90 CYCL DEF 7.2  Y+0
91 CYCL DEF 7.3  Z+0
92 ;
93 Q50 = Q50 + 60 ;Calculate the C angle further
94 CALL LBL 2 REP5 ;Repeat
95 ;
96 ;Subprogram call, move to save position
97 CALL LBL "SAVE"
98 ;
99 ;Tilt back physically
100 PLANE RESET TURN MB MAX
101 ;
102 ;Drill when tilted position
103 ;Tool call for drill
104 TOOL CALL "DRILL_D8" Z S12000 F300
105 ;
106 Q50 = 0 ;Current C angle
107 ;
108 ;Repetition for tilting to position and drilling
109 LBL 3
110 PLANE SPATIAL SPA+0 SPB+0 SPC+Q50 STAY ;Tilting the coordinate system to the current C angle
111 ;
112 ;Move datum to the tilting edge
113 CYCL DEF 7.0 DATUM SHIFT
114 CYCL DEF 7.1  X+37
115 ;
116 PLANE RELATIV SPB+60 TURN MB MAX FMAX ;Tilt B with respect to C angle
117 ;
118 L  X+12  Y+0  Z+50 R0 FMAX M3 ;Pre-positioning
119 CYCL DEF 200 DRILLING ~
    Q200=+3    ;SET-UP CLEARANCE ~
    Q201=-35   ;DEPTH ~
    Q206= AUTO ;FEED RATE FOR PLNGNG ~
    Q202=+5    ;PLUNGING DEPTH ~
    Q210=+0    ;DWELL TIME AT TOP ~
    Q203=+0    ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q211=+0    ;DWELL TIME AT DEPTH
120 M99 ;Cycle call
121 ;
122 M140 MB MAX ;Retracting
123 PLANE RESET STAY ;Tilt back mathematically
124 ;Reset the datum shift
125 CYCL DEF 7.0 DATUM SHIFT
126 CYCL DEF 7.1  X+0
127 CYCL DEF 7.2  Y+0
128 CYCL DEF 7.3  Z+0
129 ;
130 Q50 = Q50 + 60 ;Calculate the C angle further
131 CALL LBL 3 REP5 ;Repeat
132 ;
133 ;Subprogram call, move to save position
134 CALL LBL "SAVE"
135 ;
136 ;Tilt back physically
137 PLANE RESET TURN MB MAX
138 ;
139 ;End of program
140 M30
141 ;
142 ;
143 ;Subprogram, turning mode
144 LBL "TURN"
145 M140 MB MAX ;Retracting
146 M145 ;Cancel the kinematic calculation
147 FUNCTION MODE TURN ;Activate turning mode
148 M144 ;Activation kinematic calculation
149 M136 ;Switch feed rate to mm per revolution
150 LBL 0
151 ;
152 ;Subprogram, milling mode
153 LBL "MILL"
154 M140 MB MAX ;Retracting
155 M145 ;Reset the kinematic calculation
156 FUNCTION MODE MILL ;Activate milling mode
157 M137 ;Switch feed rate to mm per minute
158 ;Subprogramm call, move to save position
159 CALL LBL "SAVE"
160 L  C+0  A+0 R0 FMAX ;Move tilting axis to zero
161 LBL 0
162 ;
163 ;Subprogram, move to save position
164 LBL "SAVE"
165 L  X+400  Y+400 R0 FMAX M91 ;Safe position !machine dependent!
166 LBL 0
167 ;
168 LBL 1 ;Description of contour
169 L  Z+0  X+80
170 L  Z-17.32  X+100
171 L  Z-28.0925  X+100
172 L  Z-33  X+117
173 LBL 0
174 ;
175 ;Description of workpiece blank
176 LBL "BLANK"
177 L  X+0  Z+2
178 L  X+120
179 L  Z-38
180 L  Z-38  X+117
181 L  Z-41.0937  X+100
182 L  Z-55  X+100
183 L  Z-55  X+108.9998
184 L  Z-55.5  X+110
185 L  Z-57.5  X+110
186 L  Z-58  X+109
187 L  Z-58  X+105
188 L  Z-61.2192  X+105
189 CT  Z-62.1894  X+103.4851
190 L  Z-63.8106  X+90.5146
191 CT  Z-64.7808  X+88.9997
192 L  Z-68.2192  X+88.9997
193 CT  Z-69.1894  X+90.5146
194 L  Z-70.8106  X+103.4851
195 CT  Z-71.7808  X+105
196 L  Z-75  X+105
197 L  Z-75  X+108.9998
198 L  Z-75.5  X+110
199 L  Z-77.5  X+110
200 L  Z-78  X+109
201 L  Z-78  X+92.7
202 L  Z-81.2081  X+92.7
203 L  Z-83.2  X+95
204 L  Z-96  X+95
205 CT  Z-98  X+91
206 L  Z-98  X+85
207 L  Z-93
208 L  X+75
209 L  Z-58
210 L  X+32
211 L  Z-38
212 L  X+0
213 L  Z+2
214 LBL 0
215 END PGM 10010_EN MM